【Unity Shader学习笔记】Unity基础纹理-渐变纹理

纹理可以用来存储任何表面属性。

可以通过使用渐变纹理来实现插画风格的渲染效果。

这项技术是由Valve公司提出的。Valve使用它来渲染游戏中具有插画风格的角色。

我们使用半兰伯特模型计算漫反射。

因为我们使用的实际上是一个一维纹理：

所以在片元着色器中，我们使用fixed2(halfLambert, halfLambert)作为uv坐标进行纹理采样。

代码实现如下：

Shader "Unity Shader Book/Chapter 7/RampTexture"

{

    Properties

    {

        _Color ("Color", Color) = (1,1,1,1)

        _RampTex ("RampTex", 2D) = "white" {}

        _Specular ("Specular", Color) = (1, 1, 1, 1)

        _Gloss ("Gloss", Range(8.0, 256)) = 20

    }

    SubShader

    {

        Pass

        {

            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM

            #pragma fragment frag

            #pragma vertex vert

            #include "Lighting.cginc"

            fixed4 _Color;

            sampler2D _RampTex;

            float4 _RampTex_ST;

            fixed4 _Specular;

            float _Gloss;

            struct a2v{

                float4 vertex : POSITION;

                float3 normal : NORMAL;

                float4 texcoord : TEXCOORD;

            };

            struct v2f{

                float4 pos : SV_POSITION;

                float3 worldNormal : TEXCOORD0;

                float3 worldPos : TEXCOORD1;

                float2 uv : TEXCOORD2;

            };

            v2f vert(a2v v){

                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);

                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                o.worldPos = mul(unity_ObjectToWorld, v.vertex);

                //计算偏移后的纹理坐标

                o.uv = TRANSFORM_TEX(v.texcoord, _RampTex);

                return o;

            }

            fixed4 frag(v2f i) : SV_Target {

                fixed3 worldNormal = normalize(i.worldNormal);

                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //使用半兰伯特计算模型

                fixed halfLambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;

                //使用纹理计算漫反射颜色

                fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert, halfLambert)).rgb * _Color.rgb;

                //计算漫反射项

                fixed3 diffuse = _LightColor0.rgb * diffuseColor;

                //高光反射

                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));

                fixed3 halfdir = normalize(worldLightDir + viewDir);

                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfdir)), _Gloss);

                return fixed4(ambient + diffuse + specular, 1.0);

            }

            ENDCG

        }

    }

    FallBack "Diffuse"

}

把不同的纹理赋给应用此shader的材质，可以得到不同的效果。

使用突变的色块作为纹理可以模拟卡通风格。如下图所示。

另外，我们需要把渐变纹理的Wrap Mode设置为Clamp模式。

因为我们使用fixed2(halfLambert, halfLambert)进行纹理采样。Repeat模式下会舍弃整数部分，如果halfLambert大于1（如1.00001），会只保留0.00001，导致映射出现问题。

巴特西

【Unity Shader学习笔记】Unity基础纹理-渐变纹理

最新文章

热门文章